智能变羊宏
#showtooltip 变形术
/Cast [target=focus,harm,exists,modifier:shift]变形术; [target=mouseover, harm, exists]变形术; 变形术
/focus [target=focus,noexists] [target=focus,dead] target

功能：按shift，并且当前已经设置的焦点目标，则强制把你的焦点目标变羊。如果没按shift，并且你的鼠标当前指向敌对目标，则将你鼠标指向的目标变羊，否则将你当前目标变羊。如果你之前没有设置焦点目标，或者焦点目标已经死亡，则将你当前目标设置为焦点目标。目前还在打副本，所以用了高级羊，如果只打竞技场，请用1级羊省蓝，在竞技场里面，1级和高级效果是一样的。
强化反制宏
#showtooltip 法术反制
/stopcasting
/cancelaura 寒冰屏障
/Cast [target=focus,harm,exists,modifier:shift]法术反制; [target=mouseover, harm, exists]法术反制; 法术反制
/focus [target=focus,noexists] [target=focus,dead] target
功能：这个宏我自己觉得我写得比较牛，首先会自动打断自己的当前施法，如果在冰箱里面的话，会自动出冰箱。然后如果按了Shift，就反制焦点，没按Shift就反制鼠标指向的目标，如果鼠标没有指向目标，就反制当前目标。

机关枪宏
/stopcasting
/cast [target=风怒图腾, harm, exists] 冰枪术
/cast [target=战栗图腾, harm, exists] 冰枪术
/cast [target=地缚图腾, harm, exists] 冰枪术
/cast [target=法力之泉图腾, harm, exists] 冰枪术
/cast [target=法力之潮图腾, harm, exists] 冰枪术
/cast [target=根基图腾, harm, exists] 冰枪术
/cast [target=清毒图腾, harm, exists] 冰枪术
/cast [target=灼热图腾, harm, exists] 冰枪术
/cast [target=mouseover,harm,exists]冰枪术;冰枪术
功能：自动打图腾，没有指定图腾，就打鼠标指向目标，也没有的话就打当前目标。不会改变当前目标，需要打其他图腾的自己加

一键水元素
没水元素就召唤，有了水元素就放远程冰环
#showtooltip [pet] 冰冻术; [nopet] 召唤水元素
/cast [nopet] 召唤水元素
/click [pet] PetActionButton5

配合上面的宏，有了这个：急冷之前解散水元素
/script PetDismiss();
/cast 急速冷却

智能冰甲
/cast [combat]冰甲术(等级 1);冰甲术
战斗外补顶级冰甲，战斗中补1级冰甲，竞技场里面被集火的时候，多一个buff也是多一份存活的希望，所以需要补冰甲，但是为了省蓝，所以补1级最合算。1级冰甲少300多护甲，但是附带的减速和刺骨效果是很重要的。

超级冰箭宏
#showtooltip [modifier:alt]寒冰箭(等级 1);寒冰箭
/Cast [target=mouseover, harm, exists,modifier:alt]寒冰箭(等级 1);[modifier:alt]寒冰箭(等级 1)
/stopmacro [modifier:alt]
/Cast [target=mouseover, harm, exists]寒冰箭;寒冰箭
直接按，顶级冰箭，按了alt，就是1级冰箭，并且优先攻击鼠标指向目标，指哪打哪，堪比六脉神剑

另一个冰箭宏，很多人说更灵活
#showtooltip [modifier:alt]寒冰箭(等级 1);寒冰箭
/cast [modifier:alt][target=mouseover, harm, exists]寒冰箭(等级 1);寒冰箭
鼠标指向的目标永远用1级的，按了alt就是强制1级的，其他情况用顶级。

奥爆炸贼宏
#showtooltip 魔爆术
/cast [noharm] 魔爆术(等级 1);魔爆术
有敌对目标顶级爆，没有目标1级爆，就是针对贼突然消失让你失去目标的时候可以省蓝。

吃喝相关
/cast [modifier:alt] 造水术
/use [nomodifier:alt] 魔法山泉水
按alt造水，直接按就是喝水，面包同理，可以自己修改，我就不写了

解诅咒
/cast [target=party1] 解除次级诅咒
帮自己第一个队友解诅咒，party1里面的1可以用2-4替换，我一共写了4个宏，分别设定快捷键从F2-F5，而解自己用F1，不需要宏，但是需要打开界面设置里的自动自我施法，我强烈建议所有法师都打开这个选项，没有坏处的。

魔法石
/castsequence reset=120 制造魔法玉石, 制造魔法红宝石

吃石头
/use 法力刚玉
/use 法力红宝石
以上两个不用解释了，我习惯把两个宏分开，大家也可以参照其他宏教程把2个宏合并，不过合并会造成一些问题，我个人不提倡。

最后是一些通用宏

坐骑
#showtooltip [flyable]迅捷红色驭风者;[noflyable] 黑色军用迅猛龙哨
/use [nomounted, flyable] 迅捷红色驭风者
/castrandom [nomounted, noflyable] 紫色骷髅战马, 黑色军用迅猛龙哨, 霜狼嗥叫者的号角
/dismount [mounted]
在外域自动骑鸟，在旧大陆随机从多个坐骑里面选一个骑，已经骑乘的时候直接下马，速度非常快。

绷带宏
/use 战歌峡谷符文布绷带
/use 奥特兰克厚符文布绷带
/use 阿拉希盆地符文布绷带
/use 厚灵纹布绷带
自动根据所在战场使用对应的绷带，不在战场就用普通绷带

吃红
/use 极效治疗石
/use 特效治疗药水
/use 不稳定的治疗药水
/use 特效作战治疗药水
/use 食人魔特酿红酒

吃蓝
/use 特效法力药水
/use 特效作战法力药水
/use 不稳定的法力药水
/use 食人魔特酿蓝酒
/use 超级法力药水

转载请保留本文链接地址:[http://www.oodd.net/Games/316.html]